10  'ÚÄ  WL30000.BAS ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ  E.D.C. S.r.L. Ä¿
20  '³       TRASFERIMENTO MULTIPLO TRA  C200-ASC02 E C200HS                 ³
30  '³   -  Il programma realizza i seguenti trasferimenti:                  ³
40  '³                                                                       ³
50  '³         PLC        <---    ASCI BASIC                                 ³
60  '³                                                                       ³
70  '³         WL30000 (TERMINALE LAUMAS):                                   ³
75  '³                  9600, 8 BIT NO PARITY, HANDSHAKE OFF, STOP BITS 1    ³
80  '³                                                                       ³
90  '³  DM950,951,952,953 <--- P1%,D2%,P2%,D2%                               ³
100 '³                                                                       ³
110 '³                       - P1% Peso corrente bilancia nø1                ³
120 '³                       - D1% Prima cifra decimale peso bilancia nø1    ³
130 '³                       - P2% Peso corrente bilancia nø2                ³
140 '³                       - D2% Prima cifra decimale peso bilancia nø2    ³
150 '³                                                                       ³
160 '³                                                                       ³
165 'ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
170 CLEAR 5000
180 P1%=0:D1%=0:P2%=0:D2%=0:PESOA%=0:PESOB%=0
184 '--------- Generazione della stringa di richiesta di lettura del peso
190 RICHPESO$=CHR$(36)+CHR$(0)+CHR$(1)+CHR$(116)+CHR$(55)+CHR$(53)+CHR$(13)
250 '################### LETTURA DALLA BILANCIA Nø2 #####################
260 '----------------------- Apro la Porta di comunicazione Nø2
270 OPEN #2,"COMU:(57)"
280 '----------------------> Invio la richiesta del peso lordo alla Bilancia
285 PRINT #2,RICHPESO$;
290 '<---------------------- Aspetto che la bilancia mi risponda
300 A$=""
305 WAIT "0.5",1400
310 A$=INPUT$(14,#2)
315 '************** LETTURA VARIABILI PESO DALLA BILANCIA 2 ***************
350 PESOB%=VAL(MID$(A$,4,6))
400 P2%=INT(PESOB%/10)
450 D2%=PESOB%-P2%*10
1300 '--------------------- FINE LETTURA DALLA PORTA 2 ---------------------
1350 PRINT PESOB%,P2%,D2%,A$
1400 CLOSE #2
1420 '*********************************************************************
1440 '################### LETTURA DALLA BILANCIA Nø1 #####################
2260 '----------------------- Apro la Porta di comunicazione Nø1
2270 OPEN #1,"COMU:(57)"
2280 '----------------------> Invio la richiesta del peso lordo alla Bilancia
2285 PRINT #1,RICHPESO$;
2290 '<---------------------- Aspetto che la bilancia mi risponda 
2300 A$=""
2305 WAIT "0.5",3400
2310 A$=INPUT$(14,#1)
2390 '************** LETTURA VARIABILI PESO DALLA BILANCIA 1 ***************
2400 PESOA%=VAL(MID$(A$,4,6))
2450 P1%=INT(PESOA%/10)
2500 D1%=PESOA%-P1%*10
3300 '--------------------- FINE LETTURA DALLA PORTA 1 ---------------------
3390 GOTO 3430
3395 '************* GESTIONE ERRORE DI COMUNICAZIONE PORTA 1 **************
3400 'QUI PUOI METTERE LA GESTIONE DELL'ERRORE
3405 CLOSE #1
3415 GOTO 3440
3420 '*********************************************************************
3430 CLOSE #1
3440 '
3500 ' ############## SEZIONE DI SCRITTURA VARIABILI AL PLC ################
3505 '----------- Scrivo P1%,P2% in DM950,951 ---------------
3515 PC WRITE "@D,950,4,4I4";P1%,D1%,P2%,D2%
3540 '################ FINE PROGRAMMA: INIZIO NUOVA LETTURA ################
3600 GOTO 190